This article applies to PRTG Network Monitor 13.2 or later

Monitoring Windows Software RAID

It is possible to monitor a Windows Software RAID with PRTG. For this concern you need to create an EXE/Script Sensor which executes a corresponding VBScript.

The present article provides an approach for monitoring a RAID. The custom sensor as described here will be able to

• recognize if there is a Software RAID available (otherwise a No RAID available message will appear)
• monitor the status of a RAID: health of volume(s), failed volume(s), rebuilding volume(s).

The script is provided below. It is based on a script by Anchor: Monitoring Windows software RAID

Please refer to Serverfault for a general discussion about this topic: How do you monitor the health of a mirrored disk in Windows?

Prerequisites

Important notice: The PRTG probe which executes the script must run on the machine where the RAID is located.

Steps to Go

1. Copy the Software RAID Status Check script below.
2. Open a text editor and paste the script into it.
3. Save it as a VBScript file, for example, as SWRaid.vbs
4. Place the file in the \Custom Sensors\EXE subfolder of your PRTG installation.
5. Add an EXE/Script sensor to PRTG.
6. In the add sensor dialog, select the created SWRaid script from the list in the EXE/Script section.
7. You can leave the other settings unchanged.

After saving the new sensor, PRTG will start to monitor the RAID immediately.

Script

See below for the SWRaid.vbs script:

' Software RAID status check script

Option Explicit

Dim WshShell, oExec
Dim Line, RE0, RE1, RE2, RE3
Dim Failed

Failed = -1
' Simple variable to display status of all volumes:
' 0 = Healthy
' 1 = Rebuilding
' 2 = Failed
' 3 = Unknown

' Check version of WScript. Has to be >= 5.6 for WScript.Shell.Exec to work
If Wscript.Version < 5.6 Then
  Wscript.echo "0:WScript version < 5.6" 
  WScript.Quit(2)
End If

Set WshShell = WScript.CreateObject("WScript.Shell")

' Execute the DISKPART program and grab the output
Set oExec = WshShell.Exec("%comspec% /C echo list volume | %WINDIR%\SYSTEM32\DISKPART.EXE")

' Set up some regular expression objects
Set RE0 = New RegExp
Set RE1 = New RegExp
Set RE2 = New RegExp
Set RE3 = New RegExp

RE0.Pattern = "Healthy"
RE1.Pattern = "Mirror|RAID-5"
RE2.Pattern = "Failed|(At Risk)"
' At Risk indicates errors have been reported for a disk
' and it may need to be reactivated.
RE3.Pattern = "Rebuild"

' Check for no output
If oExec.StdOut.AtEndOfStream Then
    Failed = 3
Else
    While Not oExec.StdOut.AtEndOfStream
        
        Line = oExec.StdOut.ReadLine
        ' Tests for Mirrored or RAID-5 volumes
        If RE1.Test(Line) Then
          ' Tests for Healthy volumes
          If RE0.Test(Line) Then
            If Failed = -1 Then 
			Failed = 0
            End If    
          End If

          ' Tests for Failed RAID volumes
          If RE2.Test(Line) Then
            If Failed < 2 Then Failed = 2	
          ' Tests for Rebuilding volumes
          ElseIf RE3.Test(Line) Then
            If Failed < 0 Then Failed = 1
          End If
        End If
    WEnd
End If

' If Failed is still -1, something bad has happened, or there is no RAID
If Failed = -1 Then Failed = 3


' Print out the appropriate test result
Select Case Failed
    Case 0
      WScript.echo "0:All volumes Healthy"
      WScript.Quit(0)
    Case 1
      WScript.echo "1:Volume(s) Rebuilding"
      WScript.Quit(1)
    Case 2
      WScript.echo "2:Volume(s) have Failed"
      WScript.Quit(2)
    Case 3
      WScript.echo "0:No Raid available"
      WScript.Quit(2)
    Case Else
      WScript.Quit(Failed)
End Select